chapter 97 - pudn.comread.pudn.com/downloads151/ebook/657122/programming...getting started with vba...

Chapter 97

Introduction to VBA inAutoCAD

4015c97 8/3/01 11:08 AM

http://www.sybex.com

V isual Basic for Applications (VBA) is integrated as a standardpart of AutoCAD 2002. This means that you can use VBA forall of your AutoCAD development tasks, instead of (or in

addition to) ObjectARX and AutoLISP. If you’re already familiar withsome dialect of BASIC, you’ll find that VBA is easy to learn. If you’re aseasoned AutoLISP developer, you may find the VBA way of doingthings to be odd, but after a while it will make sense. There’s a table atthe end of this chapter that will help you translate AutoLISP conceptsto their VBA equivalents.

• Understanding ActiveX Automation

• Writing VBA Code

• Using Procedures

• Variables and Constants

• Control Structures

• Built-In Functions

• Error Handling

• Converting from AutoLISP to VBA

• If You Want to Experiment…

4015c97 8/3/01 11:08 AM


Getting Started with VBAMicrosoft’s VBA package supplies two things to AutoCAD. First, there’s the VBA languageengine itself, which does the job of interpreting any VBA code you write when yourapplication is executed. Second, there’s the VBA Integrated Development Environment(IDE), which provides you with the tools for editing and debugging your VBA code. Inthis chapter, you’ll learn the basics of the VBA language itself. The next chapter, alsofound on this CD, describes the IDE and how to integrate VBA code with the AutoCADuser interface. However, you need to know just enough about the IDE to type in and exe-cute procedures to follow along with this chapter, so here’s a quick introduction.

Launching the VBA IDETo get started, you’ll want to become familiar with the AutoCAD VBA Integrated Devel-opment Environment, or IDE. The following steps show you how to open the IDE.

1. Select Tools ➜ Macro ➜ Visual Basic Editor from an AutoCAD drop-downmenu. This opens the VBA editor in a separate window.

2. With the IDE open, you have several options to move between the IDE and theAutoCAD Window. Click the View AutoCAD button at the left end of the Edi-tor toolbar, or select View ➜ AutoCAD from an editor menu.

3. The Alt+F11 key combination also moves you from the editor back to AutoCAD.Press Alt+F11 to go from the main AutoCAD window back to the VBA editor.

You can also open the editor automatically when you load a VBA project. To do so, choose Tools ➜ Macro

➜ Load Project and make sure the Open Visual Basic Editor check box is selected.

Creating a New ModuleAt any given time, you can have more than one VBA project open in AutoCAD. (You donot need to have any project open, however.) All of the components in a project are loadedat the time the project is opened. A project can consist of any of these components:

• Modules

• Class modules

• UserForms

GETTING STARTED WITH VBA 3

4015c97 8/3/01 11:08 AM


A module is a container for VBA code. A class module is the VBA component usedto define a new type of object. A UserForm is a customizable user interface component.Class modules are an advanced topic, and you’ll learn about UserForms in Chapter 99(which is also on this CD), but for now, let’s just create a standard module. This will bea place where you can execute code samples.

If you have AutoCAD open with a default blank drawing loaded, you’ll find thatthis drawing includes a default VBA project named ACADProject.

1. To insert a new module, select Insert ➜ Module from the IDE menus, or clickthe Insert Module button on the Standard toolbar. This creates a new moduleand opens that module in the editor. The editor can display many modules atonce, since it’s a Multiple Document Interface (MDI) application.

2. While you’re learning VBA, you’ll probably find it useful to maximize themodule you’re working with. Click the Maximize button in the Module1 win-dow to enlarge it.

Creating and Running a New ProcedureModules hold VBA code, but one module can contain a lot of code. In VBA, code isbroken up into procedures. You’ll learn about the different types of procedures in amoment, but for now, let’s just create one.

1. In the Module1 window, type Sub HelloWorld and press the Enter key. VBAwill insert parentheses at the end of the procedure definition, and automaticallycreate an End Sub line to mark the end of the procedure.

2. Now type MsgBox “Hello World” in between the Sub and End Sub lines.Notice that VBA provides you with Quick Info about the arguments for theMsgBox function. For now, you can just ignore these.

3. Click the mouse anywhere off the line you’ve just typed to accept it and clearthe Quick Info.

4. Now that you’ve created a procedure, let’s run it. You can run procedures inter-actively in the VBA environment by using the Immediate window (sometimescalled the Debug window). This window may already be displayed at the bot-tom of the IDE. If not, you can open it using View ➜ Immediate Window orthe Ctrl+G keystroke combination.

CHAPTER NINETY-SEVEN • INTRODUCTION TO VBA IN AUTOCAD4

4015c97 8/3/01 11:08 AM


5. Type HelloWorld into the Immediate window to tell VBA to execute theHelloWorld procedure that you just created. The MsgBox statement creates apopup message in your AutoCAD window (and, incidentally, makes theAutoCAD window the active window, as shown in Figure 97.1).

6. Click OK in this dialog box to return to the VBA IDE. If you’ve followed alongwith the instructions in this section, your screen will look like Figure 97.2.

Figure 97.1 Results of the HelloWorld procedure

GETTING STARTED WITH VBA 5

4015c97 8/3/01 11:08 AM


Figure 97.2 The HelloWorld procedure in the VBA IDE

Shortcuts

To Launch the Visual Basic EditorSelect Tools ➜ Macro ➜ Visual Basic Editor.

To Load a VBA ProjectSelect Tools ➜ Macro ➜ Load Project.

To Create a New ProcedureType Sub or Function and the name of the procedure in a module.

To Test a ProcedureIn the Immediate window, type the name of a sub, or a question mark, and type in the name of the function, plus anyrequired arguments in parentheses.


4015c97 8/3/01 11:08 AM


To Define a VariableUse Dim plus the variable name and type.

To Define a ConstantUse Const plus the constant name and data.

To Prevent Spelling Mistakes from Creating Unwanted VariablesPlace Option Explicit at the top of every module.

To Store Multiple Items of InformationDeclare and use an array for a fixed number of items, or a collection for a variable number of items.

To Branch within Your CodeUse If…Then…Else or Select Case.

To Loop within Your CodeUse a For loop for a fixed number of iterations, or a Do loop for a variable number of iterations.

To Display a Message to the UserUse the MsgBox function.

To Request Input from the UserUse the InputBox function.

To Handle ErrorsUse On Error GoTo to direct all errors to an error trap in your code.

ProceduresYour VBA code is stored in procedures, which themselves are grouped into modules.Procedures come in two flavors: function procedures, and sub procedures, usually justcalled functions and subs. In this section, you’ll learn how to create and call both typesof procedures and how to pass information back and forth between procedures.

PROCEDURES 7

4015c97 8/3/01 11:08 AM


Subs and FunctionsThe difference between subs and functions is that functions return a value to the caller,and subs do not.

Actually, it’s more correct to say that functions can return a value, since you can execute a function with asyntax that tells VBA to throw the return value away. This chapter, though, will concentrate on learningenough VBA to do useful work as quickly as possible, without digging into every corner of the language.For a more advanced discussion of VBA, see VBA Developer’s Handbook, 2nd edition, by Ken Getz andMike Gilbert (Sybex, 2001) or Mastering AutoCAD VBA, by Marion Cottingham (Sybex, 2001).

While there is an Insert ➜ Procedure item on the VBA menu, it’s really unneces-sary. That’s because, as you saw previously for a sub, it’s simpler just to type in the Subor Function keyword, name the procedure, and let VBA do the rest. As illustrated inthe following example, you can create one of each type of procedure.

1. In the Module1 window, move the cursor below the End Sub statement, andtype Sub ShowSquare()↵. The End Sub statement appears below your newstatement, as well as a line dividing the previous End Sub from the line youjust entered.

2. Place the cursor below the End Sub statement and type Function Return-Square()↵. The Module1 window should display the following new lines, witha horizontal line dividing each entry:

Sub ShowSquare()

End SubFunction ReturnSquare()

End Function

ArgumentsOur ShowSquare and ReturnSquare procedures both square a number provided bythe user. To do this, you need to equip each procedure with an argument. An argu-ment is a placeholder for information that will be supplied at runtime. Let’s see howarguments work:

1. Go ahead and add the code to these two procedures to make them deliver thesquare. Here’s the modified version:

Sub ShowSquare(x)


4015c97 8/3/01 11:08 AM


Debug.Print x * xEnd SubFunction ReturnSquare(x)

ReturnSquare = x * xEnd Function

In each of these procedures, x is an argument. At runtime (that is, when youactually execute the procedure) you must supply a value for the argument.

2. Click below the HelloWorld entry in the Immediate window and enterShowSquare 5↵.

3. Next, enter ?ReturnSquare (7)↵. Figure 97.3 shows the Immediate windowafter executing each of these procedures.

Figure 97.3 Executing the ShowSquare and ReturnSquare procedures

Notice that the calling syntax differs between functions and subs. For a sub, yousimply supply the name of the procedure, followed by any arguments the sub takes,without parentheses. To call a function from the Immediate window, you use the ?operator followed by any arguments the function takes, surrounded by parentheses.You can think of the ? operator as meaning “What is the value of?”.

Although both procedures provide the same output in the sample, they use differ-ent methods to provide that output. The sub calls Debug.Print, which is a special bit ofVBA syntax that takes whatever follows it on the line and prints it to the Immediatewindow. The function assigns the result to its own name. This has the effect of makingthat the return value of the function.

Of course, one procedure can call other procedures. In the following example, theCallBoth procedure executes both of the other two procedures:

Sub CallBoth(x)Dim yShowSquare xy = ReturnSquare(x)

End Sub

PROCEDURES 9

4015c97 8/3/01 11:08 AM


Here, y is a local variable: a place to store a bit of information (you’ll learn moreabout variables in the next section). To call a function procedure from within anotherprocedure, you assign the value of the function procedure to a local variable.

You can also execute a sub procedure by using the special Call keyword, in which case the procedure’sarguments must be enclosed in parentheses. That is, the statements ShowSquare 4 and CallShowSquare(4) are equivalent. Most developers use the former syntax because it requires less typing.

Optional and Named ArgumentsVBA supports optional arguments: arguments that you may, but are not required to, sup-ply to a procedure. In addition, you can supply arguments either by position (according totheir position in the argument list) or by name (according to the argument name). To seethe effect of optional and named arguments on VBA syntax, you can experiment withthis function:

Function Increment(Original, Optional Amount = 1)Increment = Original + Amount

End Function

In this example, both Original and Amount are named arguments. In addition,Amount is an optional argument, with a default value of 1.You can execute the Incrementprocedure from the Immediate window in a variety of ways:

?Increment(5,2)?Increment(5)?Increment(Original:=5)?Increment(Original:=5, Amount:=2)?Increment(Amount:=2, Original:=5)

The first example treats the arguments positionally, supplying a value for each onein order. The second example does the same, but does not supply a value for theAmount argument. In this case, the Amount argument defaults to 1, and the result ofthe function is 6 (try it yourself!). The third example also omits the optional argument,but uses the named argument syntax of Name:=Value to make it clear what informa-tion is being supplied. The fourth and fifth examples show that you can supply argu-ments in whatever order you like if you’re using named arguments.


4015c97 8/3/01 11:08 AM


Don’t try to mix named and positional arguments. If you supply a named argument for any argument toa procedure, use named arguments for all the information you pass.

Variables and ConstantsUntil now, you haven’t learned about one big part of most actual procedure declarations:data types. Technically, all of the arguments and return values up to this point have beenvariants.You can think of a variant as a multipurpose data type that can hold anything.In this section, you’ll see that there are also special-purpose data types, as well as someother ways to store data than in simple variables.

Data TypesVBA supports ten specific types of data. Table 97.1 shows these data types and therange of data that each one can hold.

Table 97.1 VBA Data Types

DATA TYPE HOLDS

Boolean True or False (VBA considers –1 to be the native True value, but will interpret any non-zero value as True.)

Byte 0 to 255, without rounding

Integer –32,768 to 32,767, without rounding

Long –2,147,483,648 to 2,147,483,647, without rounding

Currency –922,337,203,685,477.5808 to 922,337,203,685,477.5807, without rounding

Single –3.402823E38 to –1.401298E–45 and 1.401298E–45 to 3.402823E38, possibly with rounding

Double –1.79769313486232E308 to –4.94065645841247E–324 and 4.94065645841247E–324 to 1.79769313486232E308, possibly with rounding

Date Any date or time value

String Text data from 0 to 2E31 characters

Variant Can hold any of the other types as well as Null (a special value for uninitialized variants and database fields)

VARIABLES AND CONSTANTS 11

4015c97 8/3/01 11:08 AM


You can declare the type of a procedure argument, a variable, or a function returntype with the As keyword. For example, you might rewrite the ShowSquare, ReturnSquare,and CallBoth procedures this way:

Sub ShowSquare(x As Integer)Debug.Print x * x

End SubFunction ReturnSquare(x As Integer) As Long

ReturnSquare = x * xEnd FunctionSub CallBoth(x As Integer)

Dim y As LongShowSquare xy = ReturnSquare(x)

End Sub

Many developers and authors working with VBA use a naming convention that specifies prefix charactersfor variable names to indicate their type. For example, an integer might be named intX and a string vari-able strName. The earlier examples in this chapter didn’t use a naming convention. From here on, though,this chapter will use the Reddick VBA Naming Convention, which is probably the most widely used namingconvention in the industry.

You can explicitly declare a variable As Variant, and use it to hold any type of datathat VBA is capable of handling. You can also leave the As clause off a variable declara-tion entirely, in which case VBA implicitly provides a variant. While this technique doesfree you from having to worry about data types, it also means that VBA won’t do anychecking at runtime to see whether data is reasonable. If you declare a variable As Inte-ger and try to put a character string in it, VBA will give you an error; if you declare thesame variable As Variant, VBA has no idea that you didn’t want it to accept strings.

Scope and LifetimeVariables declared within procedures are local variables. They’re of use only to that proce-dure, and indeed, only when the procedure is running. But VBA provides several otherways to declare variables. This code fragment shows all the ones you’ll commonly need:

Option Explicit

Public gstrSharedWithEveryone As StringPrivate mstrSharedRightHere As String


4015c97 8/3/01 11:08 AM


Public Sub Procedure1(varArg1 As Variant)Dim intI As Integer

End Sub

Private Sub Helper(varArg2 As Variant)Static intJ As Integer

End Sub

You can break down these declarations as follows:

• gstrSharedWithEveryone is a public variable (called a global variable in earlierversions of VBA). This variable can be used by any procedure in any module inthe project.

• mstrSharedRightHere is a module-level variable. This variable can be used byany procedure in the module where it’s defined.

• varArg1 and varArg2 are local arguments. They can be used only by the pro-cedures in whose argument list they appear.

• intI is a local variable. It can be used only by the procedure in which it is defined.

• intJ is also a local variable. It can be used only by the procedure in which it isdefined.

This distinction—between public, module-level, and local variables—is commonlyreferred to as the scope of the variable. Using the previous example, gstrSharedWithEvery-one has global scope, mstrSharedRightHere has module scope, and intI has local scope.

There’s also a second factor to consider in declaring variables, that of lifetime.Global and module scope variables have project lifetime: They are created when theproject is loaded, and if you set a value into one of these variables, they keep that valueuntil the project is unloaded (or you deliberately set another value into them). Localvariables have procedure lifetime: They’re created when you execute the procedure, anddiscarded when the procedure is finished. However, you can use the Static keyword(as shown for intJ above) to declare a local variable with project lifetime. What thismeans is that the value of the variable persists across calls to the procedure. If you runHelper more than once (and it contains additional code, not shown here, to assign avalue to the variable), you’ll find that intJ contains the last value you set into it, ratherthan being reinitialized each time.


4015c97 8/3/01 11:09 AM


The Option Explicit StatementYou may have noticed the line Option Explicit in the code example in the previoussection. This is a VBA statement that you can insert into any of your code modules(once per module, and by convention at the top). The effect of this statement is to tellVBA that you intend to explicitly declare all of your variables before using them. If youomit Option Explicit, VBA will automatically create a variant-type variable for anyvariable you use without declaration.

This option can protect you against an annoying and hard-to-find error. For example,if you don’t have Option Explicit set, this is legal VBA:

Function Oops() As LongDim LongVariableName As IntegerLongVariableName = 4Oops = LongVariableName * LongVarriableName

End Function

Even though it’s legal, the function as written will return 0, not 16, because one ofthe variable names is spelled differently than the other two, causing VBA to assign it sep-arate storage. If you try to run this procedure in a module with Option Explicit set,though, you’ll get an immediate compilation error: Variable Not Defined from VBA.

You can check for compilation errors at any time in VBA by selecting Debug ➜ Compile ACADproject.

Setting Option Explicit is so important that there’s a way to tell VBA to do thisfor you in every new module.

1. Select Tools ➜ Options from the VBA drop-down menus. You see the EditorOptions dialog box, shown in Figure 97.4.

2. Check the Require Variable Declaration check box (by default it’s unchecked) andyou’ll never have to worry about including Option Explicit again yourself.

Make this the first thing you do after installing AutoCAD, before you write anycode at all.


4015c97 8/3/01 11:09 AM


Figure 97.4 The Editor Options dialog box

ConstantsVBA supports constants—names for values that won’t change during the course of yourapplication. You can use constants to make your code more readable. For example, eventhough VBA doesn’t provide an automatic function to convert degrees into radians, it’seasy enough to write one:

Function DegreesToRadians1(dblDegrees As Double) _As Double

DegreesToRadians1 = (dblDegrees / 180) * 3.14159End Function

The underscore (_) followed by the Enter key (↵) combination serves as a line-continuation character inVBA, so the first two lines of this example are one line as far as the VBA interpreter is concerned.


4015c97 8/3/01 11:09 AM


Although it’s easy enough to see what this example does, you can make it a bitclearer by using a constant to represent the magic number:

Function DegreesToRadians2(dblDegrees As Double) _As Double

Const Pi = 3.14159DegreesToRadians2 = (dblDegrees / 180) * Pi

End Function

Like variables, constants can be declared with local, module, or global scope. If youneeded Pi in many places, you might define it as a global constant instead:

Public Const Pi = 3.14159Function DegreesToRadians3(dblDegrees As Double) _As DoubleDegreesToRadians3 = (dblDegrees / 180) * PiEnd Function

ArraysYou can group VBA variables into arrays—numbered collections of variables of thesame type. To declare an array, you simply tell VBA how many elements it will have:

Dim strK(1 To 5) As String

This creates an array, strK, with storage for five strings, numbered 1 through 5. Youcan assign values to members of an array, or read them out again:

Sub ArrayDemo()Dim strK(1 To 5) As StringstrK(1) = “H”strK(2) = “e”strK(3) = “l”strK(4) = “l”strK(5) = “o”Debug.Print strK(1), strK(2), strK(3), _strK(4), strK(5)

End SubArrays tend to be of limited use in VBA; in many instances, collections (discussed

below) prove more useful. However, they’re critical for one thing in AutoCAD: the VBA


4015c97 8/3/01 11:09 AM


representation of a point in AutoCAD’s Model Space is as an array of doubles. Here’swhat the code for drawing a line in AutoCAD might look like:

Sub DrawLine()Dim ptStart(1 To 3) As DoubleDim ptEnd(1 To 3) As DoubleptStart(1) = 1ptStart(2) = 1ptStart(3) = 1ptEnd(1) = 2ptEnd(2) = 2ptEnd(3) = 2ThisDrawing.ModelSpace.AddLine ptStart, ptEnd

End Sub

Each of the arrays holds the information necessary to locate one point. The first,second, and third elements of the array hold, respectively, the x-, y-, and z-coordinatesof the point in AutoCAD’s model space.

CollectionsVBA collections provide an alternative to arrays for keeping track of multiple items.Unlike arrays, which are designed to hold things that can be identified by number, collec-tions are designed for random access.You can think of a collection as a place to stash any-thing you like and to retrieve it later by name.

The CollectionDemo procedure demonstrates the syntax that you use workingwith collections:

Sub CollectionDemo()Dim col As CollectionSet col = New Collection

‘ Add three items to the collectioncol.Add 5, “First”col.Add 9, “Second”col.Add 12, “Third”

‘ Retrieve items by nameDebug.Print col.Item(“First”)Debug.Print col(“Second”)Debug.Print col(“Third”)


4015c97 8/3/01 11:09 AM


‘ Retrieve items by indexDebug.Print col.Item(1)Debug.Print col(2)Debug.Print col(3)

‘ Remove an item from the collectioncol.Remove 2

‘ And show how many items are leftDebug.Print col.Count

End Sub

Although you declare a collection with the same Dim keyword that you use for othervariables, you must also initialize the collection. That’s because a collection is a type ofobject variable—one that has more complex properties than just a storage location fordata. Initializing the variable is the purpose of this line:

Set col = New Collection

The New keyword tells VBA to create an object of the type Collection, and the Setkeyword tells VBA that you’ll use the col variable to refer to this new object.

Add is a method of the Collection object. This method takes two arguments, thefirst being the item to add, and the second being a key value that can be used later torefer to the item. You can add anything to a collection. In this case, you’re adding thethree numbers 9, 5, and 12.

The next two sections of the sample show that you can retrieve items either by key orby index (position) within the collection. Note that the keyword Item can be specified oromitted when using either syntax. That’s because Item is the default method of the collec-tion object.

Finally, you can use the Remove method to remove an item from a collection, andthe Count property to show the current number of items in a collection.

Objects, Methods, and PropertiesYou’ll run into objects, methods, and properties throughout VBA. If you’ve looked at the AutoCAD object model, you’vealready run across all three of these:

• An object is any type of variable that has complex behavior. For example, the Document object in AutoCADrepresents an entire drawing file.


4015c97 8/3/01 11:09 AM


• A method is anything that an object knows how to do. The methods of the Document object include the Openand Regen methods. You can think of methods as the verbs for an object.

• A property is anything that describes an object. The properties of the Document object include the Name andActiveLinetype properties. You can think of properties as the adjectives describing an object.

In addition to the objects provided by AutoCAD, VBA has a number of built-in objects, including the collection objectyou’ve just seen. Later in this chapter you’ll learn how to use class modules to create your own objects.

Control StructuresAlthough the original BASIC language lacked many features, most of those deficiencieshave been remedied in modern versions of BASIC, such as VBA.VBA is now a full-fledgedstructured programming language, with a full set of control structures for looping, branch-ing, and flow of control. This section will describe the control structures that are most oftenuseful in applications.

The If…Then…Else StructureTo handle branching, VBA uses an If…Then…Else structure, as shown in the followingexample:

Function IfDemo(intNum As Integer) As StringIf intNum = 1 Then

IfDemo = “One”ElseIf intNum = 2 Then

IfDemo = “Two”ElseIf intNum = 3 Then

IfDemo = “Three”Else

IfDemo = “I dunno”End If

End Function

In this structure, each If or ElseIf keyword is followed by a Boolean condition—something that can be evaluated as either True or False. When VBA encounters a condi-tion that evaluates as True, it executes the statements that follow that condition. If you

CONTROL STRUCTURES 19

4015c97 8/3/01 11:09 AM


include an Else clause, that set of statements is executed if none of the conditions is True.Notice that an End If statement is required to terminate the conditional. Figure 97.5shows the result of executing IfDemo with a variety of inputs.

Figure 97.5 Testing the IfDemo procedure

The Select Case StatementDeeply nested If…Then…Else loops can be very difficult to decipher. Always beware of dif-ficult code, because it’s a potential maintainability nightmare: If you need to modify suchcode, the chance of introducing a new error is all too large. Fortunately,VBA provides analternative branching structure for such situations, the Select Case statement. Here’s anexample of the Select Case statement syntax:

Function CaseDemo(intNum As Integer) As StringSelect Case intNum

Case 1CaseDemo = “One”

Case 2CaseDemo = “Two”

Case 3 To 5CaseDemo = “Between Three and Five”

Case 7, 9CaseDemo = “7 or 9”

Case ElseCaseDemo = “I dunno”

End SelectEnd Function

The Select Case statement works by comparing the specified expression (in thisexample, intNum) to each case in turn, until it finds one that matches. At that point,the code in that particular case is executed. Here, the return value of the procedure is


4015c97 8/3/01 11:09 AM


determined by the matching case. As you can see, the case can be a particular value, arange of values (3 to 5), or a collection of values (7, 9). You can use the Select Casestatement with any type of variable. The values of the individual cases must be thesame data type as the variable.

For LoopsSometimes your program will need to perform the same operation multiple times; forexample, to add a logo to all the drawings related to a project. VBA provides severallooping structures for repetitively executing code. The For loop is perhaps the simplestof these, providing a way to execute a set of statements a predetermined number oftimes. The For loop works by incrementing or decrementing a counter:

Sub ForDemo()Dim intI As Integer

‘ Simple For loop: intI is incremented by‘ one each time the loop is executedFor intI = 1 To 5

Debug.Print intINext intI

‘ For loop with increment: in this case,‘ 2 is added to intI with each loopFor intI = 1 To 5 Step 2


‘ Reverse For loop: here, intI is‘ decremented each time through the loopFor intI = 5 To 1 Step -1


End Sub

For loops are most useful when you know exactly how many times you need toexecute the loop. Often, you’ll use a For loop to process the elements in an array. Ifyou’re dealing with a collection, you may be better off using a Do loop, as shown in thenext section.

CONTROL STRUCTURES 21

4015c97 8/3/01 11:09 AM


Do LoopsDo loops provide an alternative to For loops when you don’t know how many times

you need to execute the loop but know when you need to stop. The simplest Do loopexecutes a statement as long as some condition is True and stops as soon as it is False:

Sub DoDemo1(intInput As Integer)Do While intInput > 0

Debug.Print intInput;intInput = intInput - 1

LoopEnd Sub

Figure 97.6 shows the output from this loop.

Figure 97.6 Output of a simple Do loop

The semicolon at the end of the Debug.Print statement tells VBA to put additional results on thesame line of output.

You can also cause a Do loop to be executed as long as a particular condition isFalse by using Until instead of While:

Sub DoDemo2(intInput As Integer)Do Until intInput = 0

Debug.Print intInput;intInput = intInput - 1

LoopEnd Sub

Do loops also allow you to test the condition at the end of the loop rather than atthe top, as shown in the next two examples:

Sub DoDemo3(intInput As Integer)


4015c97 8/3/01 11:09 AM


DoDebug.Print intInput;intInput = intInput - 1

Loop While intInput > 0End SubSub DoDemo4(intInput As Integer)

DoDebug.Print intInput;intInput = intInput - 1

Loop Until intInput = 0End Sub

A Do loop with the test at its end will always execute at least once, even if it would have been skippedentirely if the test were at the start of the loop.

The GoTo OperatorIn addition to branching and looping, VBA includes an operator to transfer flow of con-trol to another place in the program. This is the infamous GoTo, which causes executionto resume at a different spot (a label) in the procedure:

Sub GoToDemo()Debug.Print “In the demo”GoTo GoHereDebug.Print “This won’t print”

GoHere:Debug.Print “This will print”

End SubIn this example, GoHere is a label, a nonexecutable statement that serves only to

mark a place in the procedure. Although using a GoTo statement is often associated withsloppy, hard-to-decipher programming, this statement is essential in error handling inVBA, as you’ll see later in this chapter. Otherwise, you can almost always avoid GoTostatements in your code.

Built-In VBA FunctionsVBA includes a wide variety of built-in functions. While this section can’t cover all ofthem, you will learn about the most useful ones here. You may want to review the

BUILT-IN VBA FUNCTIONS 23

4015c97 8/3/01 11:09 AM


“Functions” section of the VBA online help for a more comprehensive list. You can alsouse the Object Browser (see Chapter 99 on this CD) to view all of the VBA functions.

OperatorsVBA includes support for a variety of operators. Table 97.2 summarizes these operators.Although VBA includes fairly complex operator precedence rules governing the order inwhich operators are evaluated, you can always use parentheses to force a particular orderof operations.

Table 97.2 VBA Operators

OPERATOR MEANING

^ Exponentiation (2^3 = 8)

- Negation, or Subtraction

* Multiplication (2*3 = 6)

/ Division (6/3 = 2)

\ Integer division (8\3 = 2)

Mod Modulus

+ Addition

& String concatenation (“A” & “B” = “AB”)

= Logical equality (If A = 5)

<> Logical inequality (If A <> 5)

< Less Than

> Greater Than

<= Less Than or Equal To

>= Greater Than or Equal To

Like Wildcard string comparison

Is Object equivalence

Not Logical Not

And Logical And

Or Logical Or

Xor Logical Exclusive Or


4015c97 8/3/01 11:09 AM


Table 97.2 (Continued) VBA Operators

Imp Logical Implication

Eqv Logical Equivalence

Quick InfoWith the variety of built-in functions that VBA provides, you might find it difficult toremember the arguments that you have to supply to make each function work. That’swhy VBA provides Quick Info, a way of prompting you on screen for the arguments to afunction. Figure 97.7 shows Quick Info in action.

Figure 97.7 VBA Quick Info

In this example, the Prompt argument is required. The other arguments areoptional, as shown by the square brackets surrounding each argument. The Buttons Asargument must be one of the values in the built-in enumeration VbMsgBoxStyle, whichyou can view using the Object Browser or by starting to enter the argument. Finally, thereturn value of the function will be one of the values allowed by the VbMsgBoxResultenumeration.

As you work with VBA, you’ll probably find Quick Info very helpful. If you reachthe point where you have learned the arguments for every function and Quick Info isbecoming intrusive, you can disable it by selecting Tools ➜ Options ➜ Editor.

User Interface FunctionsVBA provides two functions that are extremely useful for creating a user interface to yourprocedures. The MsgBox function displays a dialog box on screen, and returns informa-tion about which button the user clicked to dismiss the dialog box. The InputBox func-tion prompts the user for information. Both the MsgBox and InputBox function makeuse of Microsoft’s IntelliSense technology to anticipate your needs, in a way similar to theautomatic spell and grammar checking found in Microsoft Word.


4015c97 8/3/01 11:09 AM


The MsgBox function takes five arguments:

Msgbox(Prompt[, Buttons][, Title][, HelpFile, Context]

Square brackets in VBA syntax examples indicate optional arguments.

The Prompt and Title arguments supply the text and caption for the dialog box.The Buttons argument controls the appearance of the dialog box; it accepts a series ofconstants that you can see by checking the IntelliSense help for the function. The lasttwo arguments allow you to specify a help file and help topic to be used if the userpresses F1 while the dialog box is displayed.

Figure 97.8 shows the dialog box produced by the following statement:

MsgBox “Unable to Save File”, _vbAbortRetryIgnore + vbCritical, “File Error”

Figure 97.8 Sample dialog box from MsgBox

The return value from a call to the MsgBox function is a constant that indicateswhich button the user clicked. Although these constants are numeric, you shouldalways use the built-in VBA constants to evaluate this return value. That makes yourcode more readable, and it protects you against potential future changes to the literalvalues of the various constants. The MsgBoxDemo procedure shows this technique.

Sub MsgBoxDemo()Dim intRet As IntegerintRet = MsgBox(“Unable to Save File”, _vbAbortRetryIgnore + vbCritical, “File Error”)Select Case intRet

Case vbAbortDebug.Print “You chose Abort”


4015c97 8/3/01 11:09 AM


Case vbRetryDebug.Print “You chose Retry”

Case vbIgnoreDebug.Print “You chose Ignore”

End SelectEnd Sub

The InputBox function uses seven arguments, although most of the arguments areoptional:

InputBox( Prompt[, Title][, Default][, XPos][, YPos] _[, HelpFile, Context]

Again, the Prompt and Title arguments control the text and caption of the dialog box.The Default argument provides a default return value, and the next two arguments allowyou to specify where the dialog box will appear on screen. As an example, Figure 97.9shows the dialog box generated by the following call:

InputBox “Enter a Number”, “Numeric Prompt”, 27

The return value from the InputBox function is a variant containing the value thatthe user typed into the edit control in the dialog box.

Figure 97.9 Sample InputBox

String FunctionsVBA supports a wide variety of text-string manipulation functions. Historically, BASICdialects have been very strong in string handling, and VBA is no exception. Table 97.3shows the most important of these functions.


4015c97 8/3/01 11:09 AM


Table 97.3 Some VBA String Functions

FUNCTION RESULTS

Asc(strX) Returns the ASCII value of the first character in strX.

Chr(n) Returns a string whose ASCII value is n.

InStr(Start, str1, str2) Returns the position in str1 where str2 occurs as a substring.Starts looking at position Start.

LCase(strU) Returns the lowercase translation of strU.

Len(strX) Returns the number of characters in strX.

LTrim(strX) Removes leading spaces from strX.

Mid(strX, Start, Length) Returns a string of Length characters starting at position Start in strX.

Right(strX, n) Returns n characters from the right end of strX.

RTrim(strX) Removes trailing spaces from strX.

Space(n) Returns a string consisting of n spaces.

Trim(strX) Removes both leading and trailing spaces from strX.

UCase(strL) Returns the uppercase translation of strL.

Mathematical FunctionsVBA includes most of the common mathematical functions (in addition to the mathe-matical operators that you’ve already seen). Table 97.4 lists the more important of thesefunctions.

Table 97.4 Some VBA Mathematical Functions

FUNCTION RESULTS

Abs(x) Returns the absolute value of x.

Atn(x) Returns the arctangent of x.

Cos(x) Returns the cosine of x.

Int(x) Returns the largest integer less than or equal to x.

Log(x) Returns the natural logarithm of x.


4015c97 8/3/01 11:09 AM


Table 97.4 (Continued) Some VBA Mathematical Functions

Rnd(x) Returns a random number if x is positive.

Sgn(x) Returns 1 if x is positive and –1 if x is negative.

Sin(x) Returns the sine of x.

Sqr(x) Returns the square root of x.

Tan(x) Returns the tangent of x.

Like AutoCAD, VBA requires that arguments to trigonometric functions be expressed in radians.

Date/Time FunctionsVBA has a selection of functions to help you work with dates and times. It’s also possibleto do your own date and time arithmetic, once you understand how dates and times arestored. All date and time variables are double-precision floating points, and contain anumber of days and partial days since an arbitrary zero date. That means that you canadd 7, for example, to a date variable, and get the same day in the following week.

Table 97.5 shows some of the built-in functions that will help you work with datesand times in your code. Two of these functions, DateAdd and DateDiff, work withintervals. The allowable interval codes are shown in Table 97.6.

Table 97.5 Some of VBA’s Date and Time Functions

FUNCTION RESULTS

Time() Returns the current time.

Date() Returns the current date.

Now() Returns the current date and time.

DateAdd(Interval, number, date) Adds the specified number of intervals to the spec-ified date.

DateDiff(Interval, Date1, Date2) Returns the number of intervals between Date1 and Date2.

Weekday(Date) Returns the day of the week that the specified datefalls on.


4015c97 8/3/01 11:09 AM


Table 97.6 Interval Codes

CODE INTERVAL

yyyy Year

q Quarter

m Month

y Day of year (1 to 366)

d Day

w Weekday

ww Week

h Hour

n Minute

s Second

Error HandlingIt’s important to make sure that your VBA code handles any errors that occur in thecourse of your application. Errors don’t necessarily mean that you’ve written “bad”code. In VBA, it’s often necessary to provoke errors in the normal course of an applica-tion. For example, to determine whether there’s a diskette in a drive, it’s simplest to justtry to write a file to that drive and intercept the error that occurs if the drive is empty.

In this section, you’ll learn how to develop code with error handling and see howto use the Err and Debug objects to derive information about errors.

Using On Error GoToVBA’s default behavior in response to errors is quite simple: It’s designed to halt operationsand notify the user. For example, suppose you run this function from the Immediate win-dow with an input of 0:

Function ErrorDemo1(intX As Integer) As IntegerErrorDemo1 = 10 / intX

End Function


4015c97 8/3/01 11:09 AM


Of course, you can’t divide by 0, so this call will cause a runtime error. Figure 97.10shows the result.

Figure 97.10 Untrapped runtime error

You can prevent end users from viewing the code in your project, whether there has been an error or not,by using project protection. From the VBE menus, choose Tools ➜ Project Properties, select the Protectiontab, and check the Lock Project for Viewing check box.

In the dialog box that reports the runtime error, clicking the End button will simplyend execution of all code, while clicking the Debug button will suspend execution of thecode and highlight the line that caused the error.

In most applications, this default behavior is unacceptable. You’ll generally use theVBA On Error GoTo statement to send all errors to a particular spot (label) in yourcode, and deal with the errors there, to prevent VBA’s default error handling from takingover. The ErrorDemo2 function shows how this might be accomplished for our samplefunction.

Function ErrorDemo2(intX As Integer) As IntegerOn Error GoTo HandleErrErrorDemo2 = 10 / intX

ExitHere:Exit Function

HandleErr:


4015c97 8/3/01 11:09 AM


Select Case Err.NumberCase 11 ‘ Division by zero

MsgBox “Zero is not a legal input”Case Else

MsgBox Err.Number & “ “ & Err.Description, _vbCritical, “Error in ErrorDemo2”

End SelectResume ExitHere

End Function

Here’s a step-by-step analysis of this function.

1. The On Error GoTo statement tells VBA that in case of any error, it shouldresume execution at the label HandleErr.

2. The function then continues with its normal operation.

3. If nothing goes wrong, the Exit Function statement will be the last statementto be executed.

4. If any error occurs, execution continues at HandleErr.

5. The Select Case statement makes a decision based on the error number (seethe next section for a discussion of the Err object).

6. The function includes a special message for one particular error, division by 0,that the function designer was anticipating.

7. For any other error, the function posts an information message to the user.This doesn’t provide any additional information over that which VBA suppliesby default, but by handling the error, the function prevents execution frombeing halted.

8. The Resume ExitHere statement clears the error condition and allows executionto continue at the ExitHere label. By always exiting the function at the samepoint, you can avoid some future maintenance problems.

The error-handling skeleton used in this function is typical of VBA error handling.If you’re building an application for distribution to others, you’ll want to include anerror handler similar to this in every procedure.


4015c97 8/3/01 11:09 AM


The Err ObjectIn the sample error-handling code, you may have noticed the references to Err.Numberand Err.Description. These are two properties of the Err object, a self-contained piece offunctionality built into VBA. Just as AutoCAD has an object model (discussed extensivelyin Chapter 98 on this CD),VBA itself supplies a few objects. If an error occurs in yourcode, you can determine what the error is by checking the properties of the Err object,which will reflect the most recent error (if no error has occurred, Err.Number will be 0).

Table 97.7 shows the most important properties of the Err object.

Table 97.7 Properties of the Err Object

PROPERTY MEANING

Number Number of the most recent error.

Description Text of the most recent error.

Source Source of the most recent error. For example, if an error occurs when working with controls on a form, the Source will be MSForms.

LastDllError Error number from a call to the Windows API.

The Debug ObjectAnother VBA object that can be useful when dealing with code is the Debug object.The Debug object supports a single method, Print, that allows your code to send a mes-sage to the Immediate window. If you can’t figure out what’s going wrong when code ismisbehaving, you can use the Debug object to help sort things out. For example, ifthere’s a variable lngCount that is getting set to an unexpected value, you can causeyour code to print the current value of the variable to the Immediate window by insert-ing the following line:

Debug.Print lngCount

The Debug object has an effect only when you’re running your code in the editor.When users interact with your application, they won’t see these messages.


4015c97 8/3/01 11:09 AM


Converting from AutoLISP to VBAVBA is not a replacement for AutoLISP. There are still many things that are easy to doin AutoLISP but are difficult or impossible from VBA. You shouldn’t assume that VBAis the preferable technology just because it’s the newer one.

On the other hand, the ease of designing dialog boxes with UserForms (covered inChapter 99) and the accessibility of VBA make it a compelling language for simpleapplications that require a user interface. You may find yourself porting existingAutoLISP code partially or entirely to new VBA utilities to make use of VBA features.

While there’s no automated tool for converting from AutoLISP to VBA, nor exactequivalents for every AutoLISP command, there are similarities between any pair ofprogramming languages. If you’re familiar with AutoLISP, you’ll find the equivalencesin Table 97.8 useful as you come up to speed on VBA.

Table 97.8 AutoLISP to VBA Conversions

AUTOLISP COMMAND VBA EQUIVALENT

+ +

- -

* *

/ /

= =

/= <>

< <

<= <=

> >

>= >=

~ Not

1+ + 1

1- - 1

abs Abs

ads Application.ListADS

alert MsgBox

and And


4015c97 8/3/01 11:09 AM


Table 97.8 (Continued) AutoLISP to VBA Conversions

angle Utility.AngleFromXAxis

angtof Utility.AngleToReal

angtos Utility.AngleToString

arx Application.ListARX

arxload Application.LoadARX

arxunload Application.UnloadARX

ascii Asc

atan Atn

atof CDbl

atoi Cint

chr Chr

close Close

cond Select Case

cos Cos

dictadd Dictionaries.Add

dictnext Dictionaries.Item

dictremove Dictionary.Delete

dictrename Dictionary.Rename

dictsearch Dictionary.GetName, Dictionary.GetObject

entmake ActiveDocument.AddXXXX

entupd Entity.Update

equal Eqv

*error* Err

exp Exp

expt ^

findfile Dir

fix Fix, Int, or Cint

float CDbl

CONVERTING FROM AUTOLISP TO VBA 35

4015c97 8/3/01 11:09 AM



foreach For Each/Next

getangle Utility.GetAngle

getcfg, getenv Preferences object

getcorner Utility.GetCorner

getdist Utility.GetDistance

getint Utility.GetInteger

getkword Utility.GetKeyword

getorient Utility.GetOrientation

getpoint Utility.GetPoint

getreal Utility.GetReal

getstring Utility.GetString

getvar Application.GetVariable

graphscr Application.Caption

handent Handle property

if If/Then/Else

itoa Str

last Ubound

list ReDim

listp IsArray

log Log

logand And

logior Or

lsh Imp

max Max

min Min

minusp < 0

nentsel SelectionSet.SelectAtPoint

nitget Utility.InitializeUserInput

null IsNull


4015c97 8/3/01 11:09 AM



numberp TypeName

open Open

polar Utility.PolarPoint

read-char Input

read-line Line Input

regapp RegisteredApplications.Add

rem Mod

repeat Do/While

rtos Utility.RealToString

set Set

setvar Application.SetVariable

sin Sin

sqrt Sqr

ssadd SelectionSets.Add

ssdel SelectionSet.Delete

ssget SelectionSet.SelectOnScreen

sslength SelectionSet.Count

ssname SelectionSet.Name

startapp Shell

strcase StrConv

strcat &

strlen Len

substr Mid

trans Utility.TranslateCoordinates

ver Application.Version

vports Viewports

wcmatch Like

while Do/While

CONVERTING FROM AUTOLISP TO VBA 37

4015c97 8/3/01 11:09 AM



write-char, write-line Print

xload Application.LoadADS

xunload Application.UnloadADS

zerop = 0

If You Want to Experiment…The easiest way to experiment with VBA is to just start using it. The sample file suppliedwith this chapter, ch97.dvb, contains all of the examples from this chapter. You shouldopen this file, located in the “code” folder on this CD, and try the sample procedures.Then try adding some of your own procedures to the same modules, or create a moduleof your own to hold your own test procedures.

In Chapter 99, you’ll see how to integrate your VBA code with AutoCAD and Auto-CAD objects. In the meantime, you should just become familiar with VBA syntax. Sometasks you might try to do with VBA include:

• Extract the portion of a full path’s filename following the last slash to returnjust the filename.

• Write a procedure that returns the average of a set of numbers stored in an array.

• Write a procedure that uses the Pythagorean theorem to return the distancebetween two points in a 2D or 3D drawing.

You’ll also find a number of sample VBA projects in the AutoCAD Samples/VBAfolder on your hard drive if you’ve done a full install of AutoCAD.


4015c97 8/3/01 11:09 AM


chapter 97 - pudn.comread.pudn.com/downloads151/ebook/657122/programming...getting started with vba...

Documents